wiselib.testing/external_interface/iphone/iphone_radio.h

Go to the documentation of this file.

#ifndef CONNECTOR_IPHONE_RADIOMODEL_H
#define CONNECTOR_IPHONE_RADIOMODEL_H

#include "external_interface/iphone/iphone_system.h"
#include "external_interface/iphone/iphone_os_model.h"
#include "util/delegates/delegate.hpp"
#include "util/iphone_node_api/iphone_link_message.h"
#include "util/base_classes/radio_base.h"

#include "util/serialization/simple_types.h"
#include "util/pstl/vector_static.h"

#include "iPhoneRadioController.h"

namespace wiselib
{
   template<typename OsModel_P, bool IPhoneLinkRadio = false>
   class iPhoneRadioModel
      : public RadioBase<OsModel_P, uint16_t, __darwin_size_t, uint8_t>
   {
   public:
      typedef OsModel_P OsModel;
      typedef iPhoneRadioModel<OsModel> self_type;
      typedef self_type* self_pointer_t;

      typedef IPhoneLinkMessage<OsModel, typename OsModel::Radio> Message;
      
      typedef uint16_t node_id_t;
      typedef uint8_t  block_data_t;
      typedef __darwin_size_t  size_t;
      typedef uint8_t  message_id_t;
   
      typedef delegate3<void, node_id_t, size_t, block_data_t*> radio_delegate_t;
      // --------------------------------------------------------------------
      enum ErrorCodes
      {
         SUCCESS = OsModel::SUCCESS,
         ERR_UNSPEC = OsModel::ERR_UNSPEC
      };
      // --------------------------------------------------------------------
      enum SpecialNodeIds {
         BROADCAST_ADDRESS = 0xffff, 
         NULL_NODE_ID      = 0       
      };
      // --------------------------------------------------------------------
      enum Restrictions {
         // todo
         MAX_MESSAGE_LENGTH = 512    
      };
      // --------------------------------------------------------------------
      iPhoneRadioModel(iPhoneSystem& system)
         : system_(system)
      {
         iPhoneRadio_ = [[iPhoneRadioController alloc] init];
      }
      // --------------------------------------------------------------------
      virtual ~iPhoneRadioModel()
      {
         [iPhoneRadio_ release];
         iPhoneRadio_ = nil;
      }
      
      // --------------------------------------------------------------------
      void set_testbed( NSString* url, UInt16 port )
      {
         [iPhoneRadio_ setUrl:url andPort:port];
      }
      // --------------------------------------------------------------------
      int enable_radio()
      {
#ifdef IPHONE_RADIO_DEBUG
      NSLog(@"IPHONE_RADIO_DEBUG: Radio enable");
#endif
         if([iPhoneRadio_ enable] == SUCCESS) {
            radio_delegate_t d = radio_delegate_t::template from_method<self_type, &self_type::receive_message>(this);
            [iPhoneRadio_ registerReceiver: d];
            
            return SUCCESS;
         }
         return ERROR_UNSPEC;
      }
      // --------------------------------------------------------------------
      int disable_radio()
      {
#ifdef IPHONE_RADIO_DEBUG
      NSLog(@"IPHONE_RADIO_DEBUG: Radio disable");
#endif
         return [iPhoneRadio_ disable];
      }
      // --------------------------------------------------------------------
      node_id_t id()
      {    
         return [iPhoneRadio_ getRadioId];
      }
      // --------------------------------------------------------------------
      int send( node_id_t to, size_t len, block_data_t *data )
      {
#ifdef IPHONE_RADIO_DEBUG
      NSLog(@"IPHONE_RADIO_DEBUG: Send %d with lenght %d", to, len);
#endif

         if(!IPhoneLinkRadio) {
            return [iPhoneRadio_ sendTo:to withData:data withLenght:len];
         
         } else {
            Message message;
            message.set_command_type( IPHONE_LINK_MESSAGE );
            message.set_destination( to );
            message.set_source( this->id() );
            message.set_payload( len, data );
         
            [iPhoneRadio_ sendTo:to withData:(uint8_t*)(&message) withLenght:message.buffer_size()];
            return [iPhoneRadio_ sendTo:to withData:(uint8_t*)(&message) withLenght:message.buffer_size()];
         }
            
      }
      // --------------------------------------------------------------------
      void receive_message( node_id_t from, size_t len, block_data_t *buf )
      {
            
                  
         if(!IPhoneLinkRadio) {
            this->notify_receivers( from, len, buf );
         
         } else {
            switch (*buf) {
               case IPHONE_LINK_MESSAGE: 
               {

                  Message *msg = (Message*)buf;
                  
                  #ifdef IPHONE_RADIO_DEBUG
                     NSLog( @"IPHONE_RADIO_DEBUG: RECEIVED IPhoneLinkMessage from %d to %d with size %d",
                        (uint32_t)msg->source(), (uint32_t)msg->destination(), msg->payload_length() );
                  #endif
                  
                  this->notify_receivers( msg->source() , msg->payload_length(), msg->payload() );
               } break;
               
               default:
               {
                  #ifdef IPHONE_RADIO_DEBUG
                     NSLog( @"IPHONE_RADIO_DEBUG: Received message is not a IPhoneLinkMessage" );
                  #endif
               } break;
            }
         }
         
      }
      
   private:
      iPhoneSystem& system_;
      iPhoneRadioController* iPhoneRadio_;
   };
}

#endif